24.5. オラクル PL/SQL からの移植

Example 24-5. 簡単な関数

これはオラクルの関数です。

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_name IN varchar, v_version IN varchar)
RETURN varchar IS
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || '/' || v_version;
END;
/
SHOW ERRORS;

この関数を通じて、 PL/pgSQL との違いを見てみましょう。

• OR REPLACE 句は使用できません。関数を作成す る前に明示的に関数を削除することで同じような結果を得ることがで きます。

• PostgreSQLは引数に名前をつけられま せん。関数内で明示的にエイリアスしなければいけません。

• オラクルにはIN, OUT, 、 INOUT 引数を関数に渡すことができます。例え ばINOUTは引数は一つの値をうけてそのほかを返 します。PostgreSQLでは"IN" 引数だけがあり、単一の 値だけ返すことができます。

• 関数プロトタイプ内の RETURN キーワード(関数 の中ではありません)は PostgreSQL では RETURNS になります。

• PostgreSQL 関数ではシングルクォートがデリミタとして使用されて いるので、関数内ではシングルクォートをエスケープしなければいけ ません。(これが時々いらいらさせるんです。Section 24.5.1.1を参照してください)。

• PostgreSQL には/show errorsコマンドはありません。

それではこの関数が PostgreSQL に移植されるとどのようになるかみてみ ましょう。

DROP FUNCTION cs_fmt_browser_version(varchar, varchar);
CREATE FUNCTION cs_fmt_browser_version(varchar, varchar)
RETRUNS varchar AS '
DECLARE
    v_name ALIAS FOR $1;
    v_version ALIAS FOR $2;
BEGIN
    IF v_version IS NULL THEN
        return v_name;
    END IF;
    RETURN v_name || ''/'' || v_version;
END;
' LANGUAGE 'plpgsql';

Example 24-6. 他の関数を作り出す関数

以下の手続きは SELECT 文からの行をとって、効率 のために IF 文で結果を巨大な関数にうめこんでい ます。PostgreSQL とはカーソル、FORループ、シン グルクォートをエスケープする必要があるというという違いに気づくで しょう。

create or replace procedure cs_update_referrer_type_proc is 
    cursor referrer_keys is 
        select * from cs_referrer_keys 
        order by try_order;

    a_output varchar(4000); 
begin 
    a_output := 'create or replace function cs_find_referrer_type(v_host IN varchar, v_domain IN varchar, 
v_url IN varchar) return varchar is begin'; 

    for referrer_key in referrer_keys loop 
        a_output := a_output || ' if v_' || referrer_key.kind || ' like ''' || 
referrer_key.key_string || ''' then return ''' || referrer_key.referrer_type || 
'''; end if;'; 
    end loop; 

    a_output := a_output || ' return null; end;'; 
    execute immediate a_output; 
end; 
/ 
show errors

この機能を PostgreSQL で記述するとこうなるでしょう。

CREATE FUNCTION cs_update_referrer_type_proc() RETURNS integer AS '
DECLARE
    referrer_keys RECORD;  -- Declare a generic record to be used in a FOR
    a_output varchar(4000);
BEGIN 
    a_output := ''CREATE FUNCTION cs_find_referrer_type(varchar,varchar,varchar) 
                  RETURNS varchar AS '''' 
                     DECLARE 
                         v_host ALIAS FOR $1; 
                         v_domain ALIAS FOR $2; 
                         v_url ALIAS FOR $3; ''; 

    -- 
    -- Notice how we scan through the results of a query in a FOR loop
    -- using the FOR <record> construct.
    --

    FOR referrer_keys IN select * from cs_referrer_keys order by try_order LOOP
        a_output := a_output || '' if v_'' || referrer_keys.kind || '' like '''''''''' 
                 || referrer_keys.key_string || '''''''''' then return '''''' 
                 || referrer_keys.referrer_type || ''''''; end if;''; 
    END LOOP; 
  
    a_output := a_output || '' return null; end; '''' language ''''plpgsql'''';''; 
 
    -- This works because we are not substituting any variables
    -- Otherwise it would fail. Look at PERFORM for another way to run functions
    
    EXECUTE a_output; 
end; 
' LANGUAGE 'plpgsql';

Example 24-7. たくさんの文字列操作手続きと、OUT 引数

以下のオラクルの PL/SQL 手続きは、URL をパースしていくつかの要素 (ホスト、パス、問い合わせ)を返します。PL/pgSQL 関数は一つの値のみ を返すので一つの手続きとなります(Section 24.5.3をご覧ください)。PostgreSQL ではこの関数は3つの異なる手続きに分割する方法があります。一つはホ ストを返し、もう一つはパスを返し、もう一つを問い合わせを返します。

create or replace procedure cs_parse_url(
    v_url IN varchar,
    v_host OUT varchar,  -- This will be passed back
    v_path OUT varchar,  -- This one too
    v_query OUT varchar) -- And this one
is
    a_pos1 integer;
    a_pos2 integer;
begin
    v_host := NULL;
    v_path := NULL;
    v_query := NULL;
    a_pos1 := instr(v_url, '//'); --  PostgreSQLには insrt 関数はありません

    if a_pos1 = 0 then
        return;
    end if;
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    if a_pos2 = 0 then
        v_host := substr(v_url, a_pos1 + 2);
        v_path := '/';
        return;
    end if;

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    if a_pos1 = 0 then
        v_path := substr(v_url, a_pos2);
        return;
    end if;

    v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    v_query := substr(v_url, a_pos1 + 1);
end;
/
show errors;

PostgreSQL に移植したのがこのこの手続きです。

drop function cs_parse_url_host(varchar); 
create function cs_parse_url_host(varchar) returns varchar as ' 
declare 
    v_url ALIAS FOR $1; 
    v_host varchar; 
    v_path varchar; 
    a_pos1 integer; 
    a_pos2 integer; 
    a_pos3 integer; 
begin 
    v_host := NULL; 
    a_pos1 := instr(v_url,''//''); 

    if a_pos1 = 0 then 
        return '''';  -- Return a blank
    end if; 

    a_pos2 := instr(v_url,''/'',a_pos1 + 2); 
    if a_pos2 = 0 then 
        v_host := substr(v_url, a_pos1 + 2); 
        v_path := ''/''; 
        return v_host; 
    end if; 

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2 ); 
    return v_host; 
end; 
' language 'plpgsql';